# Maintainer: Dinosaur <ancient dash dinosaurus at proton dot me>
# Maintainer: AndyRTR <andyrtr@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>

_pkgname=xf86-video-fbdev
pkgname=$_pkgname-enhanced
pkgver=0.5.1
pkgrel=1
pkgdesc="X.org framebuffer video driver - enhanced"
arch=(x86_64)
license=('X11')
url="https://xorg.freedesktop.org/"
depends=('glibc')
makedepends=('xorg-server-devel-enhanced' 'X-ABI-VIDEODRV_VERSION=28.0') # git)
conflicts=('xorg-server<26.0.0.901' 'X-ABI-VIDEODRV_VERSION<28' 'X-ABI-VIDEODRV_VERSION>=29' "${_pkgname}")
provides=("${_pkgname}")
groups=('xorg-drivers-enhanced')
source=(${url}/releases/individual/driver/${_pkgname}-${pkgver}.tar.xz{,.sig})
sha512sums=('ab345d796fb6a404c44a5caec31497fd36dce8882befad644b3f6fac1969c0a4ba9243e911e86a29a149ee7b0847ba676a28a49e15f1789238f2726b9dcea1a8'
            'SKIP')
# validpgpkeys=('995ED5C8A6138EB0961F18474C09DD83CAAA50B2')
validpgpkeys+=('3BB639E56F861FA2E86505690FDD682D974CA72A') # Matt Turner <mattst88@gmail.com>

build() {
  cd $_pkgname-$pkgver

  # Since pacman 5.0.2-2, hardened flags are now enabled in makepkg.conf
  # With them, module fail to load with undefined symbol.
  # See https://bugs.archlinux.org/task/55102 / https://bugs.archlinux.org/task/54845
  export CFLAGS=${CFLAGS/-fno-plt}
  export CXXFLAGS=${CXXFLAGS/-fno-plt}
  export LDFLAGS=${LDFLAGS/-Wl,-z,now}

  ./configure --prefix=/usr
  make
}

check() {
  cd $_pkgname-$pkgver
  make check
}

package() {
  cd $_pkgname-$pkgver
  make DESTDIR="${pkgdir}" install
  install -m755 -d "${pkgdir}/usr/share/licenses/${_pkgname}"
  install -m644 COPYING "${pkgdir}/usr/share/licenses/${_pkgname}/"
}