# Maintainer: Dinosaur <ancient dash dinosaurus at proton dot me>
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>

_pkgname=xf86-video-vesa
pkgname=$_pkgname-enhanced
pkgver=2.6.0
pkgrel=3
pkgdesc="X.org vesa video driver - enhanced"
arch=(x86_64)
license=('MIT')
url="https://xorg.freedesktop.org/"
depends=('glibc')
makedepends=('xorg-server-devel-enhanced' 'X-ABI-VIDEODRV_VERSION=28.0')
conflicts=('xorg-server<26.0.0.901' 'X-ABI-VIDEODRV_VERSION<28' 'X-ABI-VIDEODRV_VERSION>=29' "${_pkgname}")
provides=("${_pkgname}")
groups=('xorg-drivers-enhanced' 'xorg-enhanced')
source=(${url}/releases/individual/driver/${_pkgname}-${pkgver}.tar.xz{,.sig})
sha512sums=('494e117c1e6e0ce4c66ac7798de54667862c62605bfd76dd9373447d40dcd0521100810c9285cbe9c159440e217954c0cad6d5219c5894e075509c7c0bc353c7'
            'SKIP')
#validpgpkeys=('DD38563A8A8224537D1F90E45B8A2D50A0ECD0D3') #  "Adam Jackson <ajax@nwnk.net>"
#validpgpkeys+=('995ED5C8A6138EB0961F18474C09DD83CAAA50B2') # "Adam Jackson <ajax@nwnk.net>"
validpgpkeys=('4A193C06D35E7C670FA4EF0BA2FB9E081F2D130E') # "Alan Coopersmith <alan.coopersmith@oracle.com>"

build() {
  cd ${_pkgname}-${pkgver}

  # Since pacman 5.0.2-2, hardened flags are now enabled in makepkg.conf
  # With them, module fail to load with undefined symbol.
  # See https://bugs.archlinux.org/task/55102 / https://bugs.archlinux.org/task/54845
  export CFLAGS=${CFLAGS/-fno-plt}
  export CXXFLAGS=${CXXFLAGS/-fno-plt}
  export LDFLAGS=${LDFLAGS/-Wl,-z,now}

  ./configure --prefix=/usr
  make
}

package() {
  cd ${_pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -d -m755 "${pkgdir}/usr/share/licenses/${_pkgname}"
  install -m644 COPYING "${pkgdir}/usr/share/licenses/${_pkgname}/"
}