# Maintainer: Dinosaur <ancient dash dinosaurus at proton dot me>
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>

_pkgname=xf86-video-voodoo
pkgname=$_pkgname-enhanced
pkgver=1.2.6
pkgrel=3
pkgdesc="X.org 3dfx Voodoo1/Voodoo2 2D video driver - enhanced"
arch=(x86_64)
url="https://xorg.freedesktop.org/"
license=('MIT')
depends=('glibc')
makedepends=('xorg-server-devel-enhanced' 'X-ABI-VIDEODRV_VERSION=28.0' 'xorgproto')
conflicts=('xorg-server<26.0.0.901' 'X-ABI-VIDEODRV_VERSION<28' 'X-ABI-VIDEODRV_VERSION>=29' "${_pkgname}")
provides=("${_pkgname}")
groups=('xorg-drivers-enhanced')
source=(${url}/releases/individual/driver/${_pkgname}-${pkgver}.tar.xz{,.sig})
sha512sums=('c889d79044438d6b15efceda07f63874063a2faa24a86d048e62c8ad1364efdfec04ff7ec662ad0749d2a7263abb14edb74e7d5ebf9a1aa880edb2b341a80a31'
            'SKIP')
validpgpkeys=('4A193C06D35E7C670FA4EF0BA2FB9E081F2D130E') # "Alan Coopersmith <alan.coopersmith@oracle.com>"

build() {
  cd ${_pkgname}-${pkgver}

  # Since pacman 5.0.2-2, hardened flags are now enabled in makepkg.conf
  # With them, module fail to load with undefined symbol.
  # See https://bugs.archlinux.org/task/55102 / https://bugs.archlinux.org/task/54845
  export CFLAGS=${CFLAGS/-fno-plt}
  export CXXFLAGS=${CXXFLAGS/-fno-plt}
  export LDFLAGS=${LDFLAGS/-Wl,-z,now}

  ./configure --prefix=/usr
  make
}

package() {
  cd ${_pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -m755 -d "${pkgdir}/usr/share/licenses/${_pkgname}"
  install -m644 COPYING "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
}