# Maintainer: Jat <chat@jat.email>

_pkgname=xorgxrdp
pkgname=xorgxrdp-glamor-git
pkgver=0.10.5
pkgrel=1
pkgdesc="Xorg drivers for xrdp, with glamor enabled. Only works on Intel and AMD GPUs."
arch=('i686' 'x86_64' 'armv6h' 'armv7l' 'aarch64')
url="https://github.com/neutrinolabs/xorgxrdp"
license=('X11')
provides=("$_pkgname")
conflicts=("$_pkgname")
depends=('xorg-server')
makedepends=('nasm' 'xorg-server-devel' 'xrdp' 'git')
checkdepends=('check' 'xorg-xdpyinfo')
options=('staticlibs')
source=(
  $pkgname::"git+$url.git"
  'glamor.patch'
)
sha256sums=('SKIP'
            '0aa0b27b66122217bd6ca2466496fe3be8738c4debe247f9af7fdaa08487622e')

prepare() {
  cd "$srcdir/$pkgname"

  # https://github.com/neutrinolabs/xrdp/issues/1029#issuecomment-724105386
  patch -p1 -i"$srcdir/glamor.patch"
}

build() {
  cd "$srcdir/$pkgname"

  ./bootstrap

  CFLAGS="$CFLAGS -ffat-lto-objects" \
    ./configure --prefix=/usr \
    --enable-glamor

  make
}

#check() {
#  cd "$srcdir/$pkgname-$pkgver"

  # https://github.com/neutrinolabs/xorgxrdp/pull/308
#  XORG=/usr/lib/Xorg make check
#}

package() {
  cd "$srcdir/$pkgname"

  make DESTDIR="$pkgdir" install
  install -Dm644 'COPYING' -t "$pkgdir/usr/share/licenses/$_pkgname"
}